Steema Central

Code: Select all

uses TeCanvas;

procedure TForm1.Chart1Click(Sender: TObject);

  function RectOf(AAxis: TChartAxis; Index:Integer):TRect;
  var tmpItem : TAxisItem;
    tmp,
    tmpW,
    tmpH : Integer;
    tmpP : TPoint;
  begin
    tmpItem:=AAxis.Items[Index];

    tmp:=tmpItem.LabelPos;
    tmpW:=AAxis.ParentChart.Canvas.TextWidth(tmpItem.Text);
    tmpH:=AAxis.ParentChart.Canvas.FontHeight;

    if AAxis.Horizontal then
    begin
      if AAxis.OtherSide then
      begin
        result.Bottom:=AAxis.PosLabels;
        result.Top:=result.Bottom-tmpH;
      end
      else
      begin
        result.Top:=AAxis.PosLabels;
        result.Bottom:=result.Top+tmpH;
      end;
    end
    else
    begin
      if AAxis.OtherSide then
         result.Left:=AAxis.PosLabels
      else
         result.Right:=AAxis.PosLabels;
    end;

    if AAxis.Horizontal then
    begin
      result.Left:=tmp-(tmpW div 2);
      result.Right:=result.Left+tmpW;
    end
    else
    begin
      result.Top:=tmp-(tmpH div 2);
      result.Bottom:=result.Top+tmpH;

      if AAxis.OtherSide then
         result.Right:=result.Left+tmpW
      else
         result.Left:=result.Right-tmpW
    end;

    if AAxis.ParentChart.View3D then
    begin
      tmpP:=AAxis.ParentChart.Canvas.Calculate3DPosition(result.TopLeft.X,result.TopLeft.Y,Round(AAxis.ParentChart.Width3D*AAxis.ZPosition*0.01));
      OffsetRect(result,tmpP.X-result.Left,tmpP.Y-result.Top);
    end;
  end;

var i: Integer;
begin
  with Chart1.Axes.Bottom do
  begin
    ParentChart.Canvas.AssignFont(Texts.Font);

    for i:=0 to Items.Count-1 do
      if PointInRect(RectOf(Chart1.Axes.Bottom, i), Chart1.GetCursorPos) then
        ShowMessage('clicked label');
  end;
end;